Offer
Uma proposta vendável: um produto, por um preço, numa unidade, por um vendedor, durante um período.
Uma Offer é uma proposta vendável: exatamente um Product, bem ou serviço, por um preço, numa unidade, vendido por uma empresa do grupo, válido por um período, opcionalmente dentro de uma Price List. “O pacote de 1800” é uma oferta de um serviço a 1800 por mês. Um Deal no CRM propõe uma oferta; o valor negociado fica no deal, o preço de lista fica aqui. Tipo BDS: schema:Offer.
Campos
O que é vendido e por quem
| Campo | Armazenamento | Significado |
|---|---|---|
| Name* | Texto | Digitado como item - preço/unidade |
| Offer # | Autonumeração | Sequência local; identifique por Name* |
| Product* | Registros vinculados | Product; exatamente um |
| Item (Name) | Fórmula | Nome do produto vinculado |
| Seller* | Registros vinculados | Organization (mirror); a empresa do grupo na proposta |
Preço
| Campo | Armazenamento | Significado |
|---|---|---|
| Price* | Moeda | Preço de lista por uma unidade; o campo é formatado com $ para qualquer moeda |
| Price Currency* | Escolha única | USD, BRL |
| Unit* | Escolha única | per month, per hour, per item, per project |
| Minimum Quantity° | Número | Menor quantidade a que a oferta se aplica; em branco significa sem mínimo |
Validade e agrupamento
| Campo | Armazenamento | Significado |
|---|---|---|
| Valid From° | Data | Primeiro dia em que pode ser proposta |
| Valid Through° | Data | Último dia; em branco significa ainda vigente |
| Price List° | Registros vinculados | Price List; uma lista ou nenhuma |
| Lifecycle Status* | Escolha única | Draft, Active, Archived |
| Offer Check | Fórmula | Fragmentos ⚠ que impedem a oferta de ser proposta |
Auditoria e classificação
| Campo | Armazenamento | Significado |
|---|---|---|
| Created At | Data de criação | Quando a linha foi criada |
| Created by | Criado por | Quem a criou |
| Intake Step | Fórmula | Encaminha linhas Draft ou sem status para o próximo passo de criação; vazio para Active e Archived |
| Tags° | Registros vinculados | Tags (mirror); opcional |
Grid de consulta capturada em 2026-10-28, antes dos intakes e dos ajustes de nomes. Use os nomes atuais das views indicados neste guia.
Regras calculadas
Offer Check
IF(LEN({Product*} & "") = 0, "⚠ No product. ", "") &
IF({Price*} = BLANK(), "⚠ No price. ", "") &
IF(LEN({Price Currency*} & "") = 0, "⚠ No currency. ", "") &
IF(LEN({Unit*} & "") = 0, "⚠ No unit. ", "") &
IF(LEN({Seller*} & "") = 0, "⚠ No seller. ", "") &
IF(AND({Valid From°} != BLANK(), {Valid Through°} != BLANK(), IS_AFTER({Valid From°}, {Valid Through°})), "⚠ Valid From is after Valid Through. ", "")Item (Name)
{Product*} & ""Vínculos e cardinalidade
Várias ofertas podem vender um produto, e o mesmo produto vendido por duas empresas são duas ofertas. Product*, Seller* e Price List° aceitam vários registros; Offer Check só sinaliza vazios, não um segundo produto ou vendedor, e não compara a moeda da oferta com a da lista. Uma oferta com Valid Through° vencido não é sinalizada.
Leitores
O CRM espelha todas as colunas de Offer, exceto Tags, como Offer (mirror). Deal.Product* vincula uma oferta; o CRM mostra Offer (Price), Offer (Item) e Offer (Unit) ao lado do Value* negociado. O uso local no CRM está em Offer no CRM. O inverso Deals (Proposed) existe só no mirror do CRM; esta base não vê quais deals usam uma oferta.
Roteamento do intake
O intake de criação usa estas fórmulas locais. Registros Active e Archived saem dos passos roteados; as mudanças de status continuam manuais.
Intake Step
IF(OR({Lifecycle Status*} = "Draft", {Lifecycle Status*} = BLANK()), IF(OR(LEN(TRIM({Name*} & "")) = 0, LEN({Product*} & "") = 0, LEN({Seller*} & "") = 0), "Create - 1", IF(OR(LEN({Price*} & "") = 0, LEN({Price Currency*} & "") = 0, LEN({Unit*} & "") = 0), "Create - 2", "Create - 3")), "")Ciclo de vida
Crie este registro pelo intake.
Comece em Draft; defina Active quando Offer Check estiver em branco e os vendedores puderem propô-la; defina Archived para aposentá-la. Nunca apague uma oferta para a qual um deal possa apontar. Um preço novo é uma oferta nova com datas novas; veja Alterar um preço.
Exemplo
Name* = Example Program - 2600/month; Product* = Example Program; Price* = 2600; Price Currency* = USD; Unit* = per month; Seller* = a empresa do grupo; Price List° = Direct - 2026; Lifecycle Status* = Active; Offer Check em branco.